¶ Script d'installation initiale pour un nouveau client
pour installation automatisée des principaux logiciels
Le script en l'état permet d'installer :
• L'EDR Sophos
• Le host Anydesk
• L'agent Acronis
• GLPI Agent (et le monitor)
¶ 1. Préparation du script
Créer un fichier script et y copier le contenu ci dessous :
@echo off
:: Changer l'encodage du terminal à UTF-8
chcp 65001 >nul
:: ===============================
:: Script d'installation initiale
:: ===============================
:: Définir les noms des fichiers d'installation
:: seuls les installers définis ET existants seront pris en comptes
:: par ex.
:: - si l'installer n'existe pas, l'app ne s'installera pas
:: - si pas besoin d'Acronis, laisser tel quel
set "ANYDESK_INSTALLER=nom_de_l_installer.msi"
set "SOPHOS_INSTALLER=nom_de_l_installer.exe"
set "GLPI_AGENT_INSTALLER=nom_de_l_installer.msi"
set "GLPI_TAG=tag_de_l_entite"
set "ACRONIS_INSTALLER=nom_de_l_installer.exe"
:: Changer le répertoire de travail à celui où se trouve le script
cd /d %~dp0
:: ===============================
:: GLPI Agent
:: ===============================
if defined GLPI_AGENT_INSTALLER if exist "%GLPI_AGENT_INSTALLER%" (
echo [*] Installation de l'Agent GLPI avec le tag "%GLPI_TAG%"...
msiexec /i "%GLPI_AGENT_INSTALLER%" /quiet SERVER=https://glpi.capeoni.io/front/inventory.php TAG="%GLPI_TAG%" RUNNOW=1 AGENTMONITOR=1 SCAN_PROFILES=1
timeout /t 10 >nul
) else (
echo [!] GLPI_AGENT_INSTALLER non défini ou fichier introuvable, installation ignorée.
)
:: ===============================
:: AnyDesk
:: ===============================
if defined ANYDESK_INSTALLER if exist "%ANYDESK_INSTALLER%" (
echo [*] Installation de AnyDesk...
msiexec /i "%ANYDESK_INSTALLER%"
timeout /t 10 >nul
echo [*] Lancement de AnyDesk...
start "" "C:\Program Files (x86)\AnyDesk-ad_06f0dc9f_msi\AnyDesk-ad_06f0dc9f_msi.exe"
timeout /t 10 >nul
) else (
echo [!] ANYDESK_INSTALLER non défini ou fichier introuvable, installation ignorée.
)
:: ===============================
:: Sophos
:: ===============================
if defined SOPHOS_INSTALLER if exist "%SOPHOS_INSTALLER%" (
echo [*] Installation de Sophos...
"%SOPHOS_INSTALLER%" --quiet --devicegroup=defaut
timeout /t 10 >nul
) else (
echo [!] SOPHOS_INSTALLER non défini ou fichier introuvable, installation ignorée.
)
:: ===============================
:: Acronis
:: ===============================
if defined ACRONIS_INSTALLER if exist "%ACRONIS_INSTALLER%" (
echo [*] Installation de Acronis...
msiexec /i "%ACRONIS_INSTALLER%" /quiet
timeout /t 10 >nul
) else (
echo [!] ACRONIS_INSTALLER non défini ou fichier introuvable, installation ignorée.
)
:: ===============================
:: Forcer mise à jour GLPI
:: ===============================
echo [*] Forcer mise à jour GLPI...
start "" "http://localhost:62354/now"
timeout /t 10 >nul
:: ===============================
:: Fin du script
:: ===============================
::cls
echo.
echo.
echo [✓] Installation terminée.
pause
Remplacer dans les lignes 14 à 18 les champs nom_de_l_installer par le nom donné au fichier d'installation correspondant au client ou à la version
Remplacer dans la lignes 17 le champ tag_de_l_entite par le TAG GLPI de l'entité concernée.
¶ 2. Préparation des sources
Enregistrer le script dans le sharepoint sous le nom init_client_concerné.cmd
\CAPEONI\GROUPE_SUPPORT - Documents\CLIENTS\ client_concerné \EXEC\INSTALL_INIT\
On ajoute dans ce même dossier les fichiers d'installation qui doivent être déployées.
Ces fichiers doivent être nommés comme dans les lignes 14 à 18 du script
¶ 3. Exécution du script
Déposer le répertoire INSTALL_INIT et son contenu sur le poste à configurer puis exécuter le script en tant qu'administrateur et attendre patiamment...
...jusqu'au message Installation terminée. Appuez sur une touche pour continuer...
Anydesk s'est normalement lancé seul, de même que la page ForceUpdate de GLPI
Vous pouvez vérifier que l'ensemble de vos applications se sont bien installées et que le poste remonte bien sur les différents services (Sophos, Acronis, GLPI, Annuaire Anydesk)
Une fois que tout est OK vous pouvez supprimer le répertoire INSTALL_INIT du poste.